নিয়ন্ত্রণ ব্যবস্থা/ওপেন সোর্স টুল/সাইল্যাব

সাইল্যাব সংখ্যাগত গণনার জন্য নির্মিত সফটওয়্যার প্যাকেজ যা জনসাধারনের ব্যাবহারের জন্য উন্মুক্ত। এটি একটি উচ্চ-স্তরীয় সংখ্যাভিত্তিক প্রোগ্রামিং ভাষা। কার্যক্ষমতার দিক থেকে সাইল্যাব, ম্যাটল্যাব -এর অনুরূপ।

সাইল্যাবে নিয়ন্ত্রন ব্যাবস্থার অধ্যয়নের জন্য প্রয়োজনীয় একটি সফটওয়্যার। এর মাধ্যমে অনেক ফাংশনের রেখচিত্রভিত্তিক রূপ প্রদর্শন করা যায়। এই সফটওয়্যারে একটি বিশ্লেষক পদ্ধতি রয়েছে, যার নাম এক্সকস যা নিয়ন্ত্রন ব্যাবস্থার প্রকৌশলীদের ব্যবহারের জন্য একটি উপযোগী সংসাধন। এই প্রবন্ধে সাইল্যাবের সেই পদ্ধতিগুলি ব্যাখ্যা করা হবে।

ধ্রুপদী নিয়ন্ত্রন ব্যাবস্থা

ট্রান্সফার ফাংশন

মচের দ্বিতীয় ক্রমের ট্রান্সফার ফাংশনটি বিবেচনা করুন;

$G(s)={\frac {5s+10}{s^{2}+4s+5}}$

সাইল্যাবে নিম্নলিখিত উপায়ে উপরের সমীকরনটি মুদ্রিত করা সম্ভব:

s = poly(0,'s');                                  // Define the complex number frequency parameter. Alternatively you can use s = %s.
TF = syslin("c", (5*s + 10) / (s^2 +4*s +5))      // Define the linear continuous transfer function
TF  =

    10 + 5s     
   ---------    
             2  
   5 + 4s + s   
   

পরবর্তী আলোচনায় এই ট্রান্সফার ফাংশনের উল্লেখ আসবে।

ট্রান্সফার ফাংশন ও স্টেট স্পেসের পারস্পরিক রূপান্তর

ট্রান্সফার ফাংশন ও স্টেট স্পেসের পারস্পরিক রূপান্তরের জন্য সাইল্যাবে বিভিন্ন রকমের উপযোগী সাধন বর্তমান।

নিম্নলিখিত পদ্ধতিতে ট্রান্সফার ফাংশন থেকে স্টেট স্পেসএ রূপান্তরিত করা যায়;

SS = tf2ss(TF)                    // TF -> SS
SS  =
      SS(1)   (state-space system:)
!lss  A  B  C  D  X0  dt  !

      SS(2) = A matrix = 
 - 2.25  - 0.25  
   4.25  - 1.75  

      SS(3) = B matrix = 
 - 2.7386128  
   2.7386128  

      SS(4) = C matrix = 
 - 1.8257419    1.110D-16  

      SS(5) = D matrix = 
   0.  

      SS(6) = X0 (initial state) = 
   0.  
   0.  

      SS(7) = Time domain = 
c

এবং স্টেট স্পেস থেকে ট্রান্সফার ফাংশনে পুনঃরূপান্তর করা যায় নিম্নলিখিত পদ্ধতিতে;

TFx = clean(ss2tf(SS))            // SS -> TF conversion. Clean removes rounding errors and is recommended.
TFx  =

    10 + 5s     
   ---------    
             2  
   5 + 4s + s
   

সিস্টেমের উপস্থাপনা

ক্রম প্রতিক্রিয়া(স্টেপ রেসপন্স)

প্রকৌশল বিদ্যা ও নিয়ন্ত্রন ব্যাবস্থায় কোন সিস্টেমের ক্রম প্রতিক্রিয়া বা স্টেপ রেস্পন্স বলতে বোঝায়, যখন সিস্টেমের নিবেশিত মান (ইনপুট)-কে ধীরে ধীরে শূন্য থেকে বাড়ানো হয়, তখন সময়ের সাপেক্ষে সিস্টেমের যে বহিপ্রতিক্রিয়া (আউটপুট) রেখচিত্রের মাধ্যমে প্রকাশ পায়, তাকেই স্টেপ রেস্পন্স বা ক্রম প্রতিক্রিয়া হিসাবে উল্লেখ করা হয়। স্টেপ রেসপন্স হলো একটি গতিশীল সিস্টেম উপস্থাপন ও তার কার্যক্ষমতা চিত্রিত করার একটি প্রচলিত পদ্ধতি। যদি আমরা উদাহরণ স্বরূপ ট্রান্সফার ফাংশনের উপর একটি একক স্টেপ ফাংশন প্রয়োগ করি, তাহলে আমরা পাবো:

নিম্নলিখিত সাইল্যাব কোড ব্যবহার করে উপরিউক্ত প্রতিক্রিয়াটি তৈরি করা হয়;

t=0:0.01:3;                         // Define a time range for the step test
plot2d(t, csim('step',t,TF));       // csim applies the step test and plot2d produces the graphical output
xlabel("Time [s]");                 // Add a title and label axis
ylabel("y1");
title("Step Response");
xgrid(1, 1, 10);                    // Define a nice grid for the plot to make it easier to read

সিএসএমআই একটি বহুমুখী ধারাবাহিক অনুকরনকারী ফাংশন বা সিমুলেশন ফাংশন যা বিভিন্নভাবে ব্যবহার করা যায়। সিএসএমআই ফাংশনের প্রথম পরামিতির মাধ্যমে কোন ধরনের অনুকরন পদ্ধতি ট্রান্সফার ফাংশনের ওপর প্রয়োগ করতে হবে তা নির্ধারণ করা হয়। এই পরামিতি নিম্নলিখিত বিকল্পগুলির মাধ্যমে এই নির্ধারণের কাজ করে:

• ক্রম(স্টেপ)
• স্পন্দন(ইমপালস্‌)
• একটি ফাংশন : $[inputs]=u(t)$
• একটি তালিকা : $list(ut,parameter1,....,parametern)$ যেমন: $inputs=ut(t,parameter1,....,parametern)$ (এখানে $ut$ হল একটি ফাংশন)
• একটি ভেক্টর, যা $ut$ ফাংশনের প্রতিটি $t$ -এর মানের জন্য সংশ্লিষ্ট $u$ -এর মান প্রদান করে

তৃতীয় প্যারামিটারটি একটি সিমো (সিংগল ইনপুট, মাল্টিপল আউটপুট অর্থাৎ একক ইনপুট বা নিবেশ মানের জন্য একাধিক আউটপুট বা ফলাফল পাওইয়া যায়) শ্রেনীভুক্ত সিস্টেম, যার ওপর সিমুলেশন বা অনুকরন পদ্ধতি প্রয়োগ করা হবে।

অপর একটি সিমুলেশন ফাংশন-ও বিদ্যমান, যা স্টেট-স্পেস সমীকরণের ওপর প্রয়োগ করা যায়। এই ফাংশনকে ডিএসআইএমইউএল নামে ডাকা হয়।

বোডি চিত্রণ

সাইল্যাবে বোডি চিত্রণের জন্য বিশেষ কমান্ড বা নির্দেশ বর্তমান।

সাইল্যাবে উপরোক্ত চিত্রণটি প্রদর্শন করার জন্য নিম্নলিখিত নির্দেশ ব্যাবহার করুন;

clf();                              // Clears the plotting window
f = 0.1:100;                        // Set-up the frequency range we want
bode(TF, f);                        // Generate the Bode plot
title("Bode Plot Example");         // Add a title

নাইকুইস্ট চিত্রণ

সাইল্যাবে নাইকুইস্ট চিত্রণের জন্য কিছু নির্দেশ আছে,

সাইল্যাবে উপরোক্ত চিত্রণটি প্রদর্শন করার জন্য নিম্নলিখিত নির্দেশ ব্যাবহার করুন;

clf();                              // Clears the plotting window
nyquist(TF);                        // Generate the Bode plot
title("Nyquist Plot Example");      // Add a title and label axis
xlabel("Real Axis");                
ylabel("yImaginary Axis");

নাইকুইস্টের জন্য ব্যাবহৃত নির্দেশে যে ট্রান্সফার ফাংশন দেওয়া হয়, তা ধারাবাহিক সময় অথবা বিচ্ছিন্ন সময়ের সাপেক্ষে নির্‌ধারিত একটি সিমো সিস্টেম (একক ইনপুট, বহু আউটপুট) -এর শ্রেনীভুক্ত করা যেতে পারে।

অতিরিক্ত অধ্যয়ন

• সাইল্যাব অফিসিয়াল সাইট
• সাইল্যাব, নিয়ন্ত্রন ব্যাবস্থা প্রকৌশলের ভিত্তিসমূহ নিয়ন্ত্রন ব্যাবস্থায় সাইল্যাবের ব্যাবহার আলোচনাকারী উৎস।

নিয়ন্ত্রণ ব্যবস্থা